传奇微信密保脚本_传奇微信密保脚本在哪

;996引擎1，其他引擎0
;用到变量(T47，T48，T49  如有冲突，请更换变量)
;T47    微信OPENID
;T48    IP地址
;T49    机器码

;补丁使用说明：
;GOM 新GOM         用68cz微信密保-GOM.Pak
;GEE GXX V8 翎风   用68cz微信密保-GEE.Pak
;996PC引擎              用68cz996.Jpk
;补丁密码：www.68cz.com

;安装说明:
;1.运行平台网关---根目录下会自动生成深度验证文件夹及子文件，请不要删除
;2.在M2上添加"补丁文件名(68cz微信密保-GOM.Pak)"资源
;3.修改脚本参数 \QuestDiary\微信密保.txt
;4.进入游戏测试【使用认证服务号，绑定密保，解绑密保，验证密保只需扫码即可，不需要再回复验证码(强烈推荐使用认证服务号)】
;微信密保测试步骤   1、微信绑定   2、微信解绑   3、IP或机器码改变后验证

;脚本添加说明
;QM登录触发添加
;#CALL [\微信密保.txt] @微信密保QM

;微信密保NPC添加
;#CALL [\微信密保.txt] @微信密保NPC

;脚本路径、脚本文件名请自行修改
;----------------------------------------------------------------------------------------------------------------------
[@微信密保NPC]
{
#IF
#ACT
MOV S$补丁编号 4
MOV N$是否996引擎 0
CLEARDELAYGOTO @微信密保状态检测

#IF
EQUAL N$是否996引擎 1
#ACT
MOV S$输入框变量 <$NPCPARAMS(1,N99)>
MOV N$关闭按钮X 415
MOV N$关闭按钮Y -35
MOV N$二微码图X 23
MOV N$二微码图Y 46
MOV N$密保按钮X 90
MOV N$密保按钮Y 180
MOV N$数字图片X 50
MOV N$数字图片Y 190
#ELSEACT
MOV S$输入框变量 N99
MOV N$关闭按钮X 435
MOV N$关闭按钮Y -10
MOV N$二微码图X 46
MOV N$二微码图Y 73
MOV N$密保按钮X 105
MOV N$密保按钮Y 210
MOV N$数字图片X 70
MOV N$数字图片Y 216

#IF
EQUAL T47
EQUAL T48
EQUAL T49
#ACT
OPENMERCHANTBIGDLG <$STR(S$补丁编号)> 10 0 0 0 0 0
BREAK
#SAY
<ImgEx:<$STR(S$补丁编号)>:15:16:17:<$STR(N$关闭按钮X)>:<$STR(N$关闭按钮Y)>/@exit>
<ImgEx:<$STR(S$补丁编号)>:18:18:18:<$STR(N$二微码图X)>:<$STR(N$二微码图Y)>>
<ImgEx:<$STR(S$补丁编号)>:19:20:21:<$STR(N$密保按钮X)>:<$STR(N$密保按钮Y)>/@绑定密保开始>

#OR
NOT EQUAL T48 <$IPADDR>
NOT EQUAL T49 <$MACHINEID>
#ACT
MOV N$验证码有效期 120
MOV S$微信密保状态 验证
MOVR S$密保验证码 100000 999999
AddTextListEx ..\..\..\..\深度验证\微信密保\密保提交\<$SERVERNAME>_<$USERNAME>.txt FSYZWX|<$STR(T47)>|<$SERVERNAME>|<$USERNAME>|<$STR(S$密保验证码)>|<$STR(N$验证码有效期)>|备用1|<$MACHINEID>|NED 0
OPENMERCHANTBIGDLG <$STR(S$补丁编号)> 14 0 0 0 0 0
BREAK
#SAY
<ImgEx:<$STR(S$补丁编号)>:15:16:17:<$STR(N$关闭按钮X)>:<$STR(N$关闭按钮Y)>/@exit>
<ImgEx:<$STR(S$补丁编号)>:18:18:18:<$STR(N$二微码图X)>:<$STR(N$二微码图Y)>>
<ImgEx:<$STR(S$补丁编号)>:25:26:27:<$STR(N$密保按钮X)>:<$STR(N$密保按钮Y)>/@@InPutInteger99(请输入您收到的验证码)>

#IF
NOT EQUAL T47
NOT EQUAL T48
NOT EQUAL T49
#ACT
OPENMERCHANTBIGDLG <$STR(S$补丁编号)> 12 0 0 0 0 0
BREAK
#SAY
<ImgEx:<$STR(S$补丁编号)>:15:16:17:<$STR(N$关闭按钮X)>:<$STR(N$关闭按钮Y)>/@exit>
<ImgEx:<$STR(S$补丁编号)>:18:18:18:<$STR(N$二微码图X)>:<$STR(N$二微码图Y)>>
<ImgEx:<$STR(S$补丁编号)>:22:23:24:<$STR(N$密保按钮X)>:<$STR(N$密保按钮Y)>/@解绑密保开始>
;=================================================================================================================================================
[@绑定密保开始]
#IF
#ACT
MOV S$数字图片
MOV N$验证码有效期 120
MOV S$微信密保状态 绑定
MOVR S$密保验证码 100000 999999
AddTextListEx ..\..\..\..\深度验证\微信密保\密保提交\<$SERVERNAME>_<$USERNAME>.txt FSBDWX|<$SERVERNAME>|<$USERNAME>|<$STR(S$密保验证码)>|<$STR(N$验证码有效期)>|备用1|<$MACHINEID>|NED 0
GOTO @开始转换图片
GOTO @微信密保状态检测
#ACT
OPENMERCHANTBIGDLG <$STR(S$补丁编号)> 11 0 0 0 0 0
#SAY
<ImgEx:<$STR(S$补丁编号)>:15:16:17:<$STR(N$关闭按钮X)>:<$STR(N$关闭按钮Y)>/@exit>
<ImgEx:<$STR(S$补丁编号)>:18:18:18:<$STR(N$二微码图X)>:<$STR(N$二微码图Y)>>
<$STR(S$数字图片)>

[@开始转换图片]
#IF
NOT EQUAL S$密保验证码
#ACT
MOV S$当前数字 <$STR(S$密保验证码)>
DEC S$当前数字 2 11
DEC S$密保验证码 1 1
INC S$数字图片 <ImgEx:<$STR(S$补丁编号)>:<$STR(S$当前数字)>:<$STR(S$当前数字)>:<$STR(S$当前数字)>:<$STR(N$数字图片X)>:<$STR(N$数字图片Y)>>
GOTO @开始转换图片

[@微信密保状态检测]
#IF
SMALL N$验证码有效期 1
#ACT
CLEARDELAYGOTO @微信密保状态检测
BREAK
#ELSEACT
MOV S$微信OPENID
GetRandomText ..\..\..\..\深度验证\微信密保\密保结果\<$SERVERNAME>_<$USERNAME>.txt S$微信OPENID 0

#IF
NOT EQUAL S$微信OPENID
#ACT
CLOSE
CLEARDELAYGOTO @微信密保状态检测
CLEARNAMELIST ..\..\..\..\深度验证\微信密保\密保结果\<$SERVERNAME>_<$USERNAME>.txt
GOTO @微信密保提示
#ELSEACT
DELAYGOTO 1000 @微信密保状态检测
;-----------------------------------------------------------------------------------------------------------------------------
[@解绑密保开始]
#IF
#ACT
MOV N$验证码有效期 120
MOV S$微信密保状态 解绑
MOVR S$密保验证码 100000 999999
AddTextListEx ..\..\..\..\深度验证\微信密保\密保提交\<$SERVERNAME>_<$USERNAME>.txt FSJCWX|<$STR(T47)>|<$SERVERNAME>|<$USERNAME>|<$STR(S$密保验证码)>|<$STR(N$验证码有效期)>|备用1|<$MACHINEID>|NED 0
#ACT
OPENMERCHANTBIGDLG <$STR(S$补丁编号)> 13 0 0 0 0 0
#SAY
<ImgEx:<$STR(S$补丁编号)>:15:16:17:<$STR(N$关闭按钮X)>:<$STR(N$关闭按钮Y)>/@exit>
<ImgEx:<$STR(S$补丁编号)>:18:18:18:<$STR(N$二微码图X)>:<$STR(N$二微码图Y)>>
<ImgEx:<$STR(S$补丁编号)>:25:26:27:<$STR(N$密保按钮X)>:<$STR(N$密保按钮Y)>/@@InPutInteger99(请输入您收到的验证码)>

[@InPutInteger99]
#IF
EQUAL <$STR(S$输入框变量)> <$STR(S$密保验证码)>
#ACT
GOTO @微信密保提示
#ELSEACT
MESSAGEBOX 验证码输入错误，请重新输入！
BREAK
;=================================================================================================================================================
[@微信密保提示]
#IF
EQUAL S$微信密保状态 绑定
#ACT
CLOSE
MOV T47 <$STR(S$微信OPENID)>
MOV T48 <$IPADDR>
MOV T49 <$MACHINEID>
MESSAGEBOX \　\【微信密保】：恭喜您成功绑定微信\　\当前绑定机器码：【<$STR(T49)>】
BREAK

#IF
EQUAL S$微信密保状态 解绑
#ACT
CLOSE
MOV T47
MOV T48
MOV T49
MAP <$STR(S$上线地图)>
MESSAGEBOX \　\　\【微信密保】：成功解绑微信，为了账号安全，请尽快绑定微信！
BREAK

#IF
EQUAL S$微信密保状态 验证
#ACT
CLOSE
MOV T48 <$IPADDR>
MOV T49 <$MACHINEID>
MAPMOVE 3 330 330 8
MESSAGEBOX \　\　\【微信密保】：微信验证通过,祝您游戏愉快!
BREAK
;=================================================================================================================================================
[@微信密保QM]
#IF
#ACT
MOV S$上线地图 MIMA
MOV S$验证地图 MMYZ

#IF
EQUAL T47
EQUAL T48
EQUAL T49
#ACT
MAP <$STR(S$上线地图)>
BREAK

#OR
NOT EQUAL T48 <$IPADDR>
NOT EQUAL T49 <$MACHINEID>
#ACT
MAP <$STR(S$验证地图)>
SENDMSG 7 提示：当前登录环境发生变化，需要【验证二级密码】，否者禁止离开！
SENDMSG 7 提示：当前登录环境发生变化，需要【验证二级密码】，否者禁止离开！
SENDMSG 7 提示：当前登录环境发生变化，需要【验证二级密码】，否者禁止离开！
BREAK

}

完整版本脚本 请下载压缩包 自行查看